Attached Files:
|
miscvaultsNOV.des [^] (15,127 bytes) 2015-11-12 01:23 [Show Content] [Hide Content]# shops.des ####################################################################
# Why not take a chance on an unidentified artefact?
NAME: nicolae_antique_artefacts
TAGS: transparent
DEPTH: D:10-, Depths
WEIGHT: 1
SHUFFLE: -m
SUBST: - = .
KFEAT: m = iron_grate
KFEAT: S = antiques shop type:Antique suffix:Artefacts count:6 ; \
any weapon randart | any armour randart | any jewellery randart w:4
MAP
.......
.-vmv-.
.v...v.
.m.S.m.
.v...v.
.-vmv-.
.......
ENDMAP
# Get away from it all.
NAME: nicolae_island_escapes
DEPTH: D:7-, !D:$, Depths, !Depths:$, Shoals, !Shoals:$, Swamp, !Swamp:$
TAGS: no_trap_gen no_item_gen no_monster_gen water_ok no_tide no_pool_fixup
WEIGHT: 5
SHUFFLE: Aa/Bb
SUBST: Aa = t, B = ..t, b = .
KFEAT: S = general shop type:Island suffix:Escapes count:7 ; \
scroll of blinking | scroll of teleportation | scroll of fog w:8 | \
potion of flight | potion of invisibility w:8 | potion of haste w:1 | \
ring of flight w:5 | ring of teleportation w:5 | ring of invisibility w:4 | \
wand of teleportation w:5 | wand of digging w:4 | wand of hasting w:1
MAP
wwwwwwwww
wwwwwwwwwww
wwwwwwwwwww
wwwwBABwwww
@wwwa...Awww
@wwwb.S>Bwww
@wwwa...Awww
wwwwBABwwww
wwwwwwwwwww
wwwwwwwwwww
wwwwwwwww
ENDMAP
# Eat the purple.
NAME: nicolae_transmutations_shop
TAGS: transparent no_item_gen no_monster_gen no_trap_gen
DEPTH: D:8-, Depths, Zot
COLOUR: m = magenta
TILE: m = dngn_transparent_wall_magenta
KFEAT: S = general shop type:Changing suffix:Room count:7 ; \
potion of cure mutation q:1 w:5 | potion of beneficial mutation q:1 w:5 | \
potion of mutation | potion of lignification | book of changes w:5 | \
wand of polymorph | sky beast chunk | book of transfigurations w:5 | \
book of alchemy w:5 | randbook disc:transmutation w:5 | \
triple sword unrand:plutonium_sword w:1
MARKER: F = lua:fog_machine { cloud_type = "mutagenic fog", pow_min = 50, \
pow_max = 50, delay = 1, size = 1, walk_dist = 0, start_clouds = 1, \
spread_rate = 0, excl_rad = 0 }
MAP
.........
.mmmmmmm.
.mFFFFFm.
.m....Fm.
....S.Fm.
.m....Fm.
.mFFFFFm.
.mmmmmmm.
.........
ENDMAP
# shoals.des ###################################################################
NAME: nicolae_shoals_this_corrosion
DEPTH: Shoals
TAGS: water_ok no_item_gen
NSUBST: % = 1:d / *:%%%%%*
KMONS: 1 = oklob plant
KMONS: 2 = siren
KMONS: p = plant
KITEM: d = any ring w:24 / any ring good_item w:5
MAP
xxxxxx
xx1WW.xx
x%.ww.pp@
x%2ww.pp@
x%.ww.pp@
xx1WW.xx
xxxxxx
ENDMAP
NAME: nicolae_shoals_kraken_party
DEPTH: Shoals, !Shoals:1
TAGS: no_monster_gen no_trap_gen water_ok
SUBST: { = {[(, . = ......wW, - = ...W
KFEAT: 1 = w
KMONS: 1 = kraken
MAP
--.@.--
xxxxxxx---xxxxxxx
x1-...........-1x
x--...........--x
x...............x
x...............x
-x...............x-
-x...............x-
.-...............-.
@-.......{.......-@
.-...............-.
-x...............x-
-x...............x-
x...............x
x...............x
x--...........--x
x1-...........-1x
xxxxxxx---xxxxxxx
--.@.--
ENDMAP
NAME: nicolae_shoals_water_shrine
DEPTH: Shoals
TAGS: water_ok no_monster_gen no_item_gen
NSUBST: 1 = 3:A / 3:E / 1:AWW / 1:EWW, 2 = 2:N / 1:Nww / *:w
KMONS: A = merfolk aquamancer
KMONS: N = water nymph
KMONS: E = water elemental
KFEAT: AE = W
KFEAT: N = w
CLEAR: _
MAP
c c
c c
_
c 1W1 c
WWWWW
c 1W2w2W1 c
WWw2wWW
c 1W2w2W1 c
WWWWW
c 1W1 c
_
c c
c c
ENDMAP
NAME: nicolae_shoals_drake_roost
DEPTH: Shoals
TAGS: water_ok no_monster_gen no_tide patrolling
SUBST: W = WWW w:6
NSUBST: . = 2:s / 2:f / 2:i / 1:sfi / 2:sfi.. / *:.
KMONS: s = steam dragon
KMONS: f = fire drake
KMONS: i = wind drake
MAP
WWWWWWWW
WWWWWWWWWWWW
WWWWWWWWWWWW
WWWWWWWWWWWWWW
WWWWW....WWWWW
WWWW......WWWW
WWWW..xx..WWWW
WWWW..xx..WWWW
WWWW......WWWW
WWWWW....WWWWW
WWWWWWWWWWWWWW
WWWWWWWWWWWW
WWWWWWWWWWWW
WWWWWWWW
ENDMAP
# overflow.des #################################################################
NAME: nicolae_xom_altar_mimics
DEPTH: D:3-
TAGS: temple_overflow_1 temple_overflow_xom uniq_altar_xom decor transparent
NSUBST: _ = 1:_ / 2:XXX_ / *:X
KFEAT: _ = altar_xom
KFEAT: X = altar_xom mimic
: interest_check(_G)
MAP
.......
._..._.
.........
.........
...........
._..._..._.
...........
.........
.........
._..._.
.......
ENDMAP
# temple.des ###################################################################
# Sometimes you just don't feel like walking all the way downstairs, you know?
NAME: nicolae_temple_entry_ecumenical
TAGS: temple_entry uniq_ecumenical_altar
WEIGHT: 1
ORIENT: float
SUBST: c : ct, - : p.
KMONS: p = plant
KFEAT: O = enter_temple
KFEAT: _ = altar_ecumenical
MAP
ccccc...ccccc
ccccc-...-ccccc
cc---..T..---cc
c-...........-c
c-._..---..O.-c
c-...-ccc-...-c
cc---ccccc---cc
ccccccccccccc
ENDMAP
# geh.des ######################################################################
NAME: nicolae_geh_amphitheater
TAGS: extra decor transparent
DEPTH: Geh, !Geh:1
SUBST: { = {[(
MAP
lllll
lllclclll
lclllllcl
llll...lll
lcl......@
lll..{...@
lcl......@
llll...lll
lclllllcl
lllclclll
lllll
ENDMAP
################################################################################
# vaults_rooms_empty.des #######################################################
NAME: nicolae_vaults_specimen_jars
TAGS: vaults_empty
KPROP: S = no_tele_into
KMASK: S = opaque
KMASK: S = no_trap_gen
KMASK: S = no_item_gen
# the W is because they're floating in solution in the jars, you see
KFEAT: S = W
KMONS: S = 0 / 9 / 8
MAP
.............
.nnn.nnn.nnn.
.nSn.nSn.nSn.
.nnn.nnn.nnn.
.............
ENDMAP
NAME: nicolae_vaults_back_hallway
TAGS: vaults_empty
MAP
.....xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx.....
.....x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.....
..(..+.................................+..(..
.....x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.x.....
.....xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx.....
ENDMAP
NAME: nicolae_vaults_bisected_slash
TAGS: vaults_empty opaque no_tele_into
WEIGHT: 2
SHUFFLE: mx
SUBST: x : mxx
MAP
.......mx
......mxm
..(..mxm.
....mxm..
...mxm...
..mxm....
.mxm..(..
mxm......
xm.......
ENDMAP
NAME: nicolae_vaults_bisected_inception
TAGS: vaults_empty opaque no_tele_into
WEIGHT: 2
NSUBST: A = 2:m / *:+
SUBST: B : xm, C : xm, D : xm, E : xm
MAP
........D........
.BB.....A.....CC.
.B......D......C.
... ...
... ...
... ...
... ...
... ...
EAE EAE
... ...
... ...
... ...
... ...
... ...
.C......D......B.
.CC.....A.....BB.
........D........
ENDMAP
NAME: nicolae_vaults_inception_statues
TAGS: vaults_empty
WEIGHT: 3
SHUFFLE: GT
MAP
G.................G
...................
.........G.........
... ...
... ...
... ...
... ...
... ...
... ...
..G G..
... ...
... ...
... ...
... ...
... ...
... ...
.........G.........
...................
G.................G
ENDMAP
NAME: nicolae_vaults_inception_scallops
TAGS: vaults_empty
WEIGHT: 3
SHUFFLE: AB
SUBST: A : GT..., B : GT...
MAP
...xxx...xxx...
.....x.....x.....
..A..+..B..+..A..
... ...
x.. ..x
xx+ +xx
x.. ..x
... ...
..B B..
... ...
x.. ..x
xx+ +xx
x.. ..x
... ...
..A..+..B..+..A..
.....x.....x.....
...xxx...xxx...
ENDMAP
# vaults_rooms_standard.des ####################################################
NAME: nicolae_vaults_network_s
TAGS: vaults_room
SHUFFLE: Aa/Bb/Cc/Dd/Ee
SUBST: Aa = ., bcde = %, % = .....%%000
NSUBST: B = . / x, C = . / x, D = . / x, E = . / x, F = . / x, G = . / x, \
H = . / x, I = . / x, J = . / x, K = . / x
KITEM: 0 = nothing / any w:5
KMONS: 0 = 0 / 0 band w:5
MAP
x..........
x..........
xxxxx.xHxDxGx..
..K%K.H%xdx%G..
..xxx.xxxDxxx..
..AaA.CcC.EeE..
..xxxBxxx.xxx..
..J%xbx%I.F%F..
..xJxBxIx.xxxxx
..........x
..........x
ENDMAP
NAME: nicolae_vaults_network_barrier
TAGS: vaults_room vaults_orient_e vaults_orient_w
SUBST: % = ....%0
NSUBST: AB = 1:., BCD = 1:., DEF = 1:., FGH = 1:., HIJ = 1:., JK = 1:., \
LM = 1:., MNO = 1:., OPQ = 1:., QRS = 1:., STU = 1:., UV = 1:., Z = 1:. / *:x
NSUBST: ab = 1:., bcd = 1:., def = 1:., fgh = 1:., hij = 1:., jk = 1:., \
lm = 1:., mno = 1:., opq = 1:., qrs = 1:., stu = 1:., uv = 1:., z = 1:. / *:x
SUBST: ABCDEFGHIJKLMNOPQRSTUVabcdefghijklmnopqrstuv = x
KITEM: 0 = nothing / any w:5
KMONS: 0 = 0 / 0 band w:5
MAP
...A%Z%L...a%z%l...
...xBxMx...xbxmx...
...C%Z%N...c%z%n...
...xDxOx...xdxox...
...E%Z%P...e%z%p...
...xFxQx...xfxqx...
...G%Z%R...g%z%r...
...xHxSx...xhxsx...
...I%Z%T...i%z%t...
...xJxUx...xjxux...
...K%Z%V...k%z%v...
ENDMAP
NAME: nicolae_vaults_network_square
TAGS: vaults_room
SHUFFLE: Aa/Bb/Cc/Dd, Ee/Ff
SUBST: AaBbCcEe = ., df = %, % = ....%00
NSUBST: D = . / x, F = . / x, G = . / x, H = . / x, I = . / x, J = . / x, \
K = . / x, L = . / x, M = . / x, N = . / x, O = . / x, P = . / x, \
Q = . / x, R = . / x, S = . / x, T = . / x, U = . / x
KITEM: 0 = nothing / any w:5
KMONS: 0 = 0 / 0 band w:5
MAP
.............
.xTxExFxGxHx.
.T%xexfx%x%H.
.xxxExFxGxxx.
.S%S.AaA.I%I.
.xxxDxUxBxxx.
.R%RdU%UbJ%J.
.xxxDxUxBxxx.
.Q%Q.CcC.K%K.
.xxxOxNxMxxx.
.P%x%x%x%x%L.
.xPxOxNxMxLx.
.............
ENDMAP
NAME: nicolae_vaults_network_periphery
TAGS: vaults_room
SUBST: % = .....%%000
NSUBST: A = . / x, B = . / x, C = . / x, D = . / x, E = . / x, F = . / x, \
G = . / x, H = . / x, I = . / x, J = . / x, K = . / x, L = . / x
NSUBST: M = x / ., N = x / ., O = x / ., P = x / .
KITEM: 0 = nothing / any w:5
KMONS: 0 = 0 / 0 band w:5
MAP
.M.M.M.M.....
.xAxBxCx.xDxN
.A%x%x%C.D%D.
.xAxBxCx.xxxN
.........E%E.
PxLx.....xxxN
.L%L..)..F%F.
Pxxx.....xFxN
.K%K.........
Pxxx.xIxHxGx.
.J%J.I%x%x%G.
PxJx.xIxHxGx.
.....O.O.O.O.
ENDMAP
NAME: nicolae_vaults_network_star
TAGS: vaults_room
SUBST: % = ...%00
NSUBST: A = . / x, B = . / x, C = . / x, D = . / x, E = . / x, F = . / x, \
G = . / x, H = . / x, I = . / x, J = . / x, K = . / x, L = . / x, M = . / x
KITEM: 0 = nothing / any w:5
KMONS: 0 = 0 / 0 band w:5
MAP
.............
.)...xBx...).
.....B%B.....
...xAxIxCx...
...A%I%I%C...
.xHxLxMxJxDx.
.H%L%M%M%J%D.
.xHxLxMxJxDx.
...G%K%K%E...
...xGxKxEx...
.....F%F.....
.)...xFx...).
.............
ENDMAP
NAME: nicolae_vaults_network_quincunx
TAGS: vaults_room
SUBVAULT: A : nico_quincunx
SUBVAULT: B : nico_quincunx
SUBVAULT: C : nico_quincunx
SUBVAULT: D : nico_quincunx
SUBVAULT: E : nico_quincunx
MAP
...................
.........).........
...................
...xAAAx...xBBBx...
...AAAAA...BBBBB...
...AAAAA...BBBBB...
...AAAAA...BBBBB...
...xAAAxCCCxBBBx...
.......CCCCC.......
.).....CCCCC.....).
.......CCCCC.......
...xDDDxCCCxEEEx...
...DDDDD...EEEEE...
...DDDDD...EEEEE...
...DDDDD...EEEEE...
...xDDDx...xEEEx...
...................
.........).........
...................
ENDMAP
NAME: nicolae_vaults_network_quinsquares
TAGS: vaults_room
SUBVAULT: A : nico_quincunx
SUBVAULT: B : nico_quincunx
SUBVAULT: C : nico_quincunx
SUBVAULT: D : nico_quincunx
SUBVAULT: E : nico_quincunx
NSUBST: a = x / ., b = x / ., c = x / .
MAP
.............
.xAAAxaxBBBx.
.AAAAA.BBBBB.
.AAAAAaBBBBB.
.AAAAA.BBBBB.
.xAAAxaxBBBx.
.b.b.b.......
.xDDDxcxEEEx.
.DDDDD.EEEEE.
.DDDDDcEEEEE.
.DDDDD.EEEEE.
.xDDDxcxEEEx.
.............
ENDMAP
NAME: nicolae_vaults_network_quincunx_subvault
TAGS: unrand nico_quincunx allow_dup
SUBST: % = ....%0
NSUBST: BDF = 1:x, ABHI = 1:., KFJE = 1:., CDIJ = 1:.
SUBST: ABCDEFGHIJK = x
KITEM: 0 = nothing / any w:5
KMONS: 0 = 0 / 0 band w:5
MAP
.xA
G%H%B
xKxIx
F%J%C
ExD
ENDMAP
NAME: nicolae_vaults_bisected_exclaves
TAGS: vaults_room opaque no_tele_into
WEIGHT: 2
SHUFFLE: abcdefghijk
SUBST: abcd = m, e : xm, f : xm, ghijk = x, % = %0
MAP
.....a.....
.xex.x..)..
.f%d.b.....
.x.xcx.xix.
.g...0.j%h.
.x.xkxkx.x.
.h%j.0...g.
.xix.xcx.x.
.....b.d%f.
..)..x.xex.
.....a.....
ENDMAP
NAME: nicolae_vaults_inception_network
TAGS: vaults_room
WEIGHT: 3
NSUBST: p = x / ., q = x / ., r = x / ., s = x / .
NSUBST: A = . / x, B = . / x, C = . / x, D = . / x, E = . / x, F = . / x, \
G = . / x, H = . / x, I = . / x, J = . / x, K = . / x, L = . / x, M = . / x, \
N = . / x, O = . / x, P = . / x, Q = . / x, R = . / x, S = . / x, T = . / x, \
U = . / x, V = . / x, W = . / x, X = . / x, Y = . / x, Z = . / x, 1 = . / x, \
2 = . / x, 3 = . / x, 4 = . / x, 5 = . / x, 6 = . / x
SUBST: % = .....%0
KITEM: 0 = nothing / any w:5
KMONS: 0 = 0 / 0 band w:5
MAP
.........................
.x6xpxAxBxCxDxExFxGxqxHx.
.6%6.A%x%x%x%x%x%x%G.H%H.
.x6xpxAxBxCxDxExFxGxqxHx.
.p.p.................q.q.
.x5x. .xIx.
.5%5. .I%I.
.xxx. .xxx.
.4%4. .J%J.
.xxx. .xxx.
.3%3. .K%K.
.xxx. .xxx.
.2%2. .L%L.
.xxx. .xxx.
.1%1. .M%M.
.xxx. .xxx.
.Z%Z. .N%N.
.xxx. .xxx.
.Y%Y. .O%O.
.xYx. .xOx.
.s.s.................r.r.
.xXxsxWxVxUxTxSxRxQxrxPx.
.X%X.x%x%x%x%x%x%x%Q.P%P.
.xXxsxWxVxUxTxSxRxQxrxPx.
.........................
ENDMAP
NAME: nicolae_vaults_inception_corners
TAGS: vaults_room
WEIGHT: 3
SHUFFLE: abcdef
SUBST: a = +, bcdef = x, ) = )00. %:5, % = %., 0 = 0.
MAP
......fx....xf......
.)...de......ed...).
...%bc..)..)..cb%...
..%xa..........ax%..
..ba ab..
.dc. .cd.
fe.. ..ef
x... ...x
..). .)..
.... ....
.... ....
..). .)..
x... ...x
fe.. ..ef
.dc. .cd.
..ba ab..
..%xa..........ax%..
...%bc..)..)..cb%...
.)...de......ed...).
......fx....xf......
ENDMAP
# vaults_rooms_hard.des ########################################################
NAME: nicolae_vaults_holding_cells
TAGS: vaults_hard
NSUBST: 1 = 4:1 / 1:2 / 1:3 / *:., . = 2:^ / *:.
KPROP: P = no_tele_into
KMASK: P = opaque
KMASK: P = no_trap_gen
KMASK: P = no_item_gen
KMONS: P = human ; nothing / orc ; nothing / elf ; nothing / troll ; nothing / \
centaur ; nothing / kobold ; nothing
KFEAT: g = iron_grate
KFEAT: ^ = alarm trap
KMONS: 1 = vault guard
KMONS: 2 = vault warden
KMONS: 3 = ironheart preserver / ironbrand convoker
MAP
xxxxxxxxx
xPg..1xxx
xxx1...xx
xPg....1x
xxx1.1...
xPg....1x
xxx1...xx
xPg..1xxx
xxxxxxxxx
ENDMAP
swampvaultNOV.des [^] (933 bytes) 2015-11-15 03:00 [Show Content] [Hide Content]# swamp.des ####################################################################
# Each room starts with twenty-seven hydra heads, just arranged differently.
NAME: nicolae_swamp_rune_108_heads
TAGS: transparent no_monster_gen no_item_gen
PLACE: Swamp:$
ORIENT: float
SUBST: h = 1--, - = wtp.., z = tt..p, 0 = 000.
NSUBST: 1 = 27:1 / 2:wtp.. / *:., 3 = 9:3 / *:., 9 = 3:9 / *:., L = 1:L / *:.
KMONS: p = plant
KMONS: 1 = one-headed hydra
KMONS: 3 = three-headed hydra
KMONS: 9 = nine-headed hydra
KMONS: L = the lernaean hydra
KITEM: L = decaying rune of Zot
KFEAT: 1239LO. = . / W w:5
MAP
ttttttttttttttz@@@
tcccccccccccctz..@
tc---..+...-cz0.0@
tc-999.+.LL-cz...@
tc-999.+.LL-c.0.0z
tc.999-c...-c...zz
tc...--cccccc+++ct
tc+++cccchhhh111ct
tc...---ch111111ct
tc.3333-ch11111hct
tc-3333-ch11111hct
tc-3333.+111111hct
tc-3333.+111111hct
tc----..+11hhhhhct
tcccccccccccccccct
tttttttttttttttttt
ENDMAP
monasteryfix.des [^] (2,285 bytes) 2015-11-19 04:02 [Show Content] [Hide Content]NAME: nicolae_zot_draconian_monastery
DEPTH: Zot, !Zot:$
ORIENT: float
TAGS: no_trap_gen no_monster_gen no_item_gen
MONS: draconian monk / base draconian w:15, patrolling draconian zealot, patrolling draconian knight
MONS: patrolling draconian scorcher
SHUFFLE: ]}), rybgmq, DZF
MARKER: + = lua:restrict_door()
# The choice of altar might matter more once monster gods are better implemented.
# Till then, it's just a style thing.
KFEAT: _ = altar_xom / altar_lugonu / altar_zin / altar_the_shining_one / \
altar_makhleb / altar_yredelemnul
SUBST: 1 = 1.
# What kind of holy books would draconians have?
KITEM: D = book of the Dragon
KITEM: Z = randbook numspells:4 spells:summon_demon&fireball&animate_dead&airstrike title:the_Zealot
KITEM: F = randbook numspells:4 spells:bolt_of_fire&fireball&sticky_flame&conjure_flame title:Fire_and_Brimstone
KITEM: _ = manual of invocations
COLOUR: r = red, y = yellow, b = blue, g = green, m = magenta, q = cyan, c = magenta
TILE: r = dngn_transparent_stone_red, y = dngn_transparent_stone_yellow, \
b = dngn_transparent_stone_blue, m = dngn_transparent_stone_magenta, \
g = dngn_transparent_stone_green, q = dngn_transparent_stone
KFEAT: rybgmq = n
MAP
@.......................@
ccccccccccccqqcrrcyycbbcggcmmcqqcrrccccccccccc
cG............G..G..G..G..G..G..G..ccc.ccc.ccc
c...ccccc..T.......................cc...c...ccl
c]2.cccDccccc..1..1..1..1..1..1..1.c..1...1..cl
c...cc...cc........................cc.......ccll
cG..+..2....c.cc.cc.cc.cc.cc.cc.cc.cT........clll
cccccc...cccc.cc.cc.cc.cc.cc.cc.cc.ccc.......clllll
ccccTc...cccc......................ccc..1..1.c....l
@qc......1.........................+.........+..3.@
@mF.4.._......1..1..1..1..1..1..1..+.........+.T..@
@qc......1.........................+.........+..3.@
ccccTc...cccc......................ccc..1..1.c....l
cccccc...cccc.cc.cc.cc.cc.cc.cc.cc.ccc.......clllll
cG..+..2....c.cc.cc.cc.cc.cc.cc.cc.cT........clll
c...cc...cc........................cc.......ccll
c}2.cccZccccc..1..1..1..1..1..1..1.c..1...1..cl
c...ccccc..T.......................cc...c...ccl
cG............G..G..G..G..G..G..G..ccc.ccc.ccc
ccccccccccccqqcrrcyycbbcggcmmcqqcrrccccccccccc
@.......................@
ENDMAP
|