|
Attached Files |
 vaultssubmission.des [^] (15,323 bytes) 2013-04-11 02:33 [Show Content] [Hide Content]# Vaults Rooms Empty. ################################################
NAME: nicolae_vaults_hallways_thing
TAGS: vaults_empty
SUBST: a : x.
MAP
aaxx..xxx..xxaa
aaax..xxx..xaaa
xaaa..xxx..aaax
xxaa..xxx..aaxx
....(.xxx.(....
.......x.......
xxxxx.....xxxxx
xxxxxx.(.xxxxxx
xxxxx.....xxxxx
.......x.......
....(.xxx.(....
xxaa..xxx..aaxx
xaaa..xxx..aaax
aaax..xxx..xaaa
aaxx..xxx..xxaa
ENDMAP
NAME: nicolae_vaults_little_ls
TAGS: vaults_empty
SUBST: g : xg
NSUBST: a = 1:+ / *:x
NSUBST: b = 1:+ / *:x
NSUBST: c = 1:+ / *:x
NSUBST: d = 1:+ / *:x
NSUBST: e = 1:+ / *:x
NSUBST: f = 1:+ / *:x
NSUBST: g = 1:+ / *:x
NSUBST: h = 1:+ / *:x
SUBST: x = x:80 n:10 +:5
MAP
x.a.b.c.x
..a.b.c..
aaa.b.ccc
....b....
ddddxeeee
....g....
fff.g.hhh
..f.g.h..
x.f.g.h.x
ENDMAP
NAME: nicolae_vaults_little_squares_5
TAGS: vaults_empty allow_dup
NSUBST: a = 1:+ / *:xx+
NSUBST: b = 1:+ / *:xx+
SHUFFLE: cd
SUBST: c : +, d = x+
MAP
xxxxx..xx
xxxxx..xx
xx..xbx..
xx..c.b..
xxxcxdxxx
..a.d..xx
..xax..xx
xx..xxxxx
xx..xxxxx
ENDMAP
NAME: nicolae_vaults_little_squares_6
TAGS: vaults_empty allow_dup
SHUFFLE: AB, CD
SUBST: AC : +
NSUBST: B = 1:+ / *:xx+
NSUBST: D = 1:+ / *:xx+
NSUBST: E = 1:+ / *:xx+
NSUBST: F = 1:+ / *:xx+
MAP
...xxx..
.(.E.C..
...xCxDx
xExx.D.x
x.A.xxFx
xAxBx...
..B.F.(.
..xxx...
ENDMAP
# Vaults Rooms Standard. #############################################
NAME: nicolae_vaults_alarming
TAGS: vaults_room
NSUBST: s = 1:S / *:.
KITEM: i = any
KMONS: S = vault sentinel
KFEAT: i = alarm trap / .
MAP
xxsxsxx
xi...ix
s.....s
x..(..x
s.....s
xi...ix
xxsxsxx
ENDMAP
NAME: nicolae_vaults_arrows
TAGS: vaults_room
SUBST: $ = $:27 %:9 *:3 |:1
KMONS: B = 0 band
MAP
xxxxxxxxx...xxxxxxxxx
x......$n...n$......x
x.0.xxxxx...xxxxx.0.x
x....xx...0...xx....x
x.x...xx.....xx...x.x
x.xx...xx...xx...xx.x
x.xxx...xx.xx...xxx.x
x$x.xx...x+x...xx.x$x
xnx..xx.......xx..xnx
......xx.....xx......
...0...+..B..+...0...
......xx.....xx......
xnx..xx.......xx..xnx
x$x.xx...x+x...xx.x$x
x.xxx...xx.xx...xxx.x
x.xx...xx...xx...xx.x
x.x...xx.....xx...x.x
x....xx...0...xx....x
x.0.xxxxx...xxxxx.0.x
x......$n...n$......x
xxxxxxxxx...xxxxxxxxx
ENDMAP
NAME: nicolae_vaults_big_ls
TAGS: vaults_room
WEIGHT: 50000
SUBST: g : xg
NSUBST: a = 1:+ / *:x
NSUBST: b = 1:+ / *:x
NSUBST: c = 1:+ / *:x
NSUBST: d = 1:+ / *:x
NSUBST: e = 1:+ / *:x
NSUBST: f = 1:+ / *:x
NSUBST: g = 1:+ / *:x
NSUBST: h = 1:+ / *:x
NSUBST: i = 1:+ / *:x
NSUBST: j = 1:+ / *:x
NSUBST: k = 1:+ / *:x
NSUBST: l = 1:+ / *:x
SUBST: x = x:80 n:10 +:5
SUBST: . = .:75 %:5 0:5
MAP
x.a.b.c.d.e.x
..a.b.c.d.e..
aaa.b.c.d.eee
....b.c.d....
bbbbb.c.ddddd
......c......
ffffffxgggggg
......j......
hhhhh.j.kkkkk
....h.j.k....
iii.h.j.k.lll
..i.h.j.k.l..
x.i.h.j.k.l.x
ENDMAP
NAME: nicolae_vaults_border_crossing
TAGS: vaults_room
SHUFFLE: AB
KMONS: W = vault warden
SUBST: G : xxx...GTb, A : +, B : +x
MAP
x.0.0.x
xx...xx
xG.W.Gx
xxABAxx
xG.W.Gx
xx...xx
x.0.0.x
ENDMAP
NAME: nicolae_vaults_stairing_the_circle
TAGS: vaults_room
NSUBST: ( = 1:0 / 2:0( / 2:0(( / *:(.
MAP
xxx.....xxx
xx....(....xx
xx..(.....(..xx
x.....xxx.....x
x.(.xxxxxxx.(.x
....xxxxxxx....
...xxxxxxxxx...
.(.xxxxxxxxx.(.
...xxxxxxxxx...
....xxxxxxx....
x.(.xxxxxxx.(.x
x.....xxx.....x
xx..(.....(..xx
xx....(....xx
xxx.....xxx
ENDMAP
NAME: nicolae_vaults_what_the_h
TAGS: vaults_room
SUBST: % = %$
MAP
...........
....x0x....
..(.xxx.(..
....x%x....
.xxx...xxx.
.0x%.(.%x0.
.xxx...xxx.
....x%x....
..(.xxx.(..
....x0x....
...........
ENDMAP
NAME: nicolae_vaults_windows_and_doors_thing
TAGS: vaults_room no_monster_gen
WEIGHT: 50000
SHUFFLE: AC/BD, EF
SUBST: B = m, C = 0, D = %, E = +, F : xxxm
NSUBST: A = 1:+ / *:x
MAP
...........
.xAxBxxxxx.
.x.xDFC..A.
.x.E.xxExx.
.xCx....DB.
.xFx.(.xFx.
.BD....xCx.
.xxExx.E.x.
.A..CFDx.x.
.xxxxxBxAx.
...........
ENDMAP
NAME: nicolae_vaults_yaktaur_gun_rack
TAGS: vaults_room no_monster_gen no_item_gen
MONS: yaktaur w:8 / yaktaur band w:4 / yaktaur captain w:2 / yaktaur captain band w:1
KITEM: b = bolt w:3 / bolt good_item w:2
KITEM: c = crossbow w:4 / crossbow good_item w:1
MAP
xxxxxxx
xcccccx
x......
x.1....
x......
xbbbbbx
xxxxxxx
ENDMAP
# Vaults Rooms Hard. #################################################
NAME: nicolae_vaults_branching_niches
TAGS: vaults_hard vaults_orient_s no_monster_gen no_item_gen
SUBST: + : +.
KMONS: m = 0 w:12 / 9 w:3 / 8 w:1 / nothing w:6
KITEM: m = nothing / % / $ / * w:5 / | w:1
MAP
xmxxxmxxxmxxxmx
x+xxx+xxx+xxx+x
x.....xxx.....x
x+x.x+xxx+x.x+x
xmx.xmxxxmx.xmx
xxx.xxxxxxx.xxx
xxx.........xxx
xxx.xxx.xxx.xxx
xmx.xmx.xmx.xmx
x+x.x+x.x+x.x+x
x.....x.x.....x
x+xxx+x.x+xxx+x
xmxxxmx.xmxxxmx
xxxxxxx.xxxxxxx
ENDMAP
NAME: nicolae_vaults_c_with_doors
TAGS: vaults_hard vaults_orient_e no_monster_gen no_item_gen
NSUBST: A = 1:+ / *:x
SUBST: $ = $$%, B = 0., 0 = 900
MAP
xxxxxxxxxxx
xB.B...B..x
x.$$xAxAxAx
xB$$xBxBxBx
x.xxx+x+x+x
x.AB+......
xBxxx.(..(.
x.AB+.(..(.
xBxxx.(..(.
x.AB+......
x.xxx+x+x+x
xB$$xBxBxBx
x.$$xAxAxAx
xB.B...B..x
xxxxxxxxxxx
ENDMAP
NAME: nicolae_vaults_meeting
TAGS: vaults_hard vaults_orient_s patrolling no_monster_gen
KMONS: S = vault sentinel
KMONS: G = vault guard
KMONS: W = vault warden
KMONS: P = ironheart preserver
KMONS: C = ironbrand convoker
SUBST: | = ||*
MAP
xxxxxxx
xxx%*|*%xxx
xxG+..S..+Gxx
x..xnnnnnx..x
x.P...C...P.x
x...........x
x..W.....W..x
xx...GGG...xx
xxxx+++xxxx
xx...xx
x...x
ENDMAP
NAME: nicolae_vaults_quartermaster
TAGS: vaults_hard
NSUBST: 0 = 1:9 / *:0
KFEAT: % = alarm trap / . w:30
KITEM: % = any
MAP
xxxxx.xxxxx
x...+0+...x
x.x.xxx.x.x
x..0%x%0..x
x+x%xxx%x+x
.0xxxxxxx0.
x+x%xxx%x+x
x..0%x%0..x
x.x.xxx.x.x
x...+0+...x
xxxxx.xxxxx
ENDMAP
# Shoals vaults. #####################################################
NAME: nicolae_shoals_so_close
DEPTH: Shoals:1-4
TAGS: no_pool_fixup water_ok no_item_gen no_trap_gen no_monster_gen
KPROP: YycfZ. = no_tide
KPROP: ZYcf. = no_rtele_into
KMONS: c = patrolling hungry ghost
NSUBST: f = 1:g / 2:f / *:.
KITEM: g = meat ration / bread ration / beef jerky
KITEM: f = meat ration / bread ration / nothing w:20
: dgn.delayed_decay(_G, 'c', 'human skeleton')
SUBST: Z = yY
KFEAT: y = w
KFEAT: Y = W
MAP
wwwwwww
wwwwwwwww
wwwyyyyywww
wwwyyyyyyywww
wwwyyZZZZyyywww
wwyyZZYYYZyyywww
wwyyZY...YZyyyww
wwyyZY.c.Yyyyyyw
wwyyZY..Yyyffyyw
wwyyZYYyyyffyyw
wwyyyyyyyyyyww
wwyyyyyyyyww
wwwwwwwwww
ENDMAP
NAME: nicolae_shoals_c_island
DEPTH: Shoals:1-4
TAGS: water_ok no_pool_fixup
KPROP: .wW}xtC = no_tide
SHUFFLE: }])
SUBST: y = Ww, z = w
KFEAT: C = any shop
MAP
xxxxxx
xtttttttxx
xtt.........xz
xx....WWWWW...xz
x...xwwwWwww...z
x..xwwwwWwwwww.z
yx..xwwwWWWwwwwwz
x..xxwwwW}Wwwwwwz
xCx..wwwWWWwwww.z
x..t.twwwwwwwww.z
yttt.ttwwwwwww..z
tt....xxwwww...z
ttt..........yz
yyy........yz
yyy....yyz
yyyyyy
ENDMAP
NAME: nicolae_shoals_dead_sea_scrolls
DEPTH: Shoals
SUBST: Z = PWs., p = P.., s = sW
KMONS: Ps = plant
KPROP: .WwpPsd = no_tide
KFEAT: y = w
KFEAT: s = W
KITEM: d = any scroll w:30 / nothing w:20 / any randbook w:1
MAP
xxxxx
xxxxdxxxx
xxddxPxxxxx
xxddxpPxxxx
xxxxxppppxx
xxxpp...ppxx
xxpp..ZZZZZxy
xxpp.ZZwwwwwyy
xxxp.ZZwwwwwyy
xxxx..Zwwwwyyy
xxx..Zwwwwyyy
xx..Zwwwyyy
@@Zwwwyy
ENDMAP
NAME: nicolae_shoals_siren_and_animal_friends
DEPTH: Shoals
TAGS: patrolling no_monster_gen
SUBST: w = f:4 w W
KMONS: f = bat w:5 / big fish w:5 / griffon / harpy / hippogriff / kraken w:1 / \
raven w:5 / sea snake / shark / sky beast w:1 / snapping turtle / \
steam dragon w:1 / alligator w:5 / alligator snapping turtle / fire crab w:1 / \
anaconda w:1 / water moccasin w:5 / electric eel w:1
KMONS: s = siren
KFEAT: sf = w
MAP
www
wwwww
wwwwwww
wwwswww
wwwwwww
wwwww
www
ENDMAP
NAME: nicolae_shoals_hunting_party
DEPTH: Shoals:2-5
TAGS: no_item_gen no_monster_gen
KMONS: i = merfolk impaler band / merfolk javelineer band
SUBST: : = .:3 h:1, W = .W
: dgn.delayed_decay(_G, 'h', 'big fish corpse / giant goldfish corpse / snapping turtle corpse / shark corpse')
MAP
WWWWWWW
WW:::WW
W:::::W
W:i:i:W
W:::::W
WW:::WW
WWWWWWW
ENDMAP
NAME: nicolae_shoals_isolated_beach
DEPTH: Shoals:2-5
TAGS: water_ok no_pool_fixup
NSUBST: { = 1:{ / *:.
SUBST: b = .wW, r = ..Wxx
KPROP: wW.{x1 = no_tide
SHUFFLE: {([
KMONS: 1 = merfolk / merfolk impaler w:5 / mermaid w:5 / nothing w:20
KFEAT: : = . / W
KFEAT: y = w
MAP
yyyyyyyy
yywwwwwwyy
yywwbbbbwwyy
yyywb{.1.bwwyy
yyxxxxxrr.bwwwyy
yxxr{.1.1rbbww::
yxr{rr.rr..bww:@
yxr{rr{rr1.bww:@
yxr{rr.rr..bww:@
yxxr{.1.1rbbww::
yyxxxxxrr.bwwwyy
yyywb{.1.bwwyy
yywwbbbbwwyy
yywwwwwwyy
yyyyyyyy
ENDMAP
NAME: nicolae_shoals_wave_tunnel
DEPTH: Shoals
TAGS: water_ok transparent
SUBST: b = .W, + = .++
KMONS: m = merfolk / nothing w:5
MAP
xxxxxxxxxwwwwwwwxxxxx
xx.......xxbbbbbxx...@
xx....m....xx.m.xx...m@
xxx.m.......m.xx+xx.m...@
@...m.xx+xx.m.......m.xxx
@m...xx.m.xx....m....xx
@...xxbbbbbxx.......xx
xxxxxwwwwwwwxxxxxxxxx
ENDMAP
NAME: nicolae_shoals_flooded_hall
DEPTH: Shoals:1-4
SHUFFLE: }}]]))>
KPROP: .123wqx = no_tide
SUBST: . = ....W, w = wWW..., q = w, x = xxxc
KFEAT: 123 = . w:40 / W
KMONS: 1 = merfolk / nothing w:5
KMONS: 2 = merfolk / merfolk aquamancer / merfolk javelineer / merfolk impaler / nothing w:45
KMONS: 3 = mermaid / siren w:5 / nothing w:5
MAP
.......
...xxxxx...
.1..x.3.x..1..
....xx.2.xx........
..xxxx..w..xxxxxxxx.
.xx..2.www.2..1..1.@
.x}1wwwwqwwwwwwwwww@
.x]1wwwwqwwwwwwwwww@
.xx..2.www.2..1..1.@
..xxxx..w..xxxxxxxx.
....xx.2.xx........
.1..x.3.x..1..
...xxxxx...
.......
ENDMAP
NAME: nicolae_shoals_water_elemental_grotto
DEPTH: Shoals:1-4
TAGS: no_pool_fixup no_monster_gen no_trap_gen no_item_gen water_ok
KPROP: .xrR-Ww = no_tide
NSUBST: - = 1:] / *:-
NSUBST: - = 3:z / *:-
SUBST: r = xx:, R = xxW, ] = ]}):
KMONS: - = nothing w:20 / plant w:5 / water elemental w:1
KMONS: z = water elemental
KFEAT: -z = . / W
KMONS: W = nothing w:50 / plant
KFEAT: m = w
MARKER: m = lua:fog_machine { cloud_type = "thin mist", pow_min = 1, \
pow_max = 3, delay = 10, start_clouds = 1, size_min = 2, \
size_max = 3, spread_rate = 33 }
MAP
xxxx.......
xxxx...xxxx@
xx.....xxrrxx
x..x..xxwWrrxx
xx..xxxxmwW--Rxx
xm--r-WwwWW--Rwx
xr----WWWW---rRx
xr------------rx
xr------WWWW--rx
xxr----WWmwW--rx
xrRWWWWWWWW-rxx
xxRWmWW-----rxx
xxRwWW-----rrx
xxRRR----rmxx
xxxxrrrrrrxx
xxxxxxxx
ENDMAP
# Custom shop vaults. ################################################
# Evocable jewellery, magical staves, and miscellaneous items.
NAME: nicolae_hardware_store
DEPTH: D:4-
TAGS: transparent
SUBST: m = mb
KFEAT: s = general shop type:Hardware suffix:Store ; any deck | any wand w:90 | any rod | \
ring of invisibility | ring of flight | ring of teleportation | \
amulet of rage | staff of channeling w:3 | air elemental fan w:3 | \
bottled efreet w:3 | lamp of fire w:3 | box of beasts w:3 | \
stone of earth elementals w:3 | lantern of shadows w:3 | disc of storms w:3 | \
crystal ball of energy w:3 | scroll of recharging w:5 | manual of evocations w:2 | \
ring of teleport control
KMONS: s = kobold ; wand of flame | wand of frost | wand of magic darts
MAP
.....
.m.m.
..s..
.m.m.
.....
ENDMAP
# Sells only evil items.
NAME: nicolae_evil_shop
TAGS: transparent
DEPTH: D:6-
SUBST: G : YlG
# I couldn't decide on just one alliterative name.
: local shopname = util.random_from({"type:Blasphemy suffix:Boutique",
: "type:Evil suffix:Emporium", "type:Profane suffix:Products",
: "type:Sacrilege suffix:Store", "type:Wicked suffix:Wares"})
: kfeat("s = general shop " .. shopname .. " ; \
: potion of blood | any weapon ego:draining w:15 | any weapon ego:pain w:15 | \
: any weapon ego:reaping w:15 | any weapon ego:vampiricism w:15 | demon blade w:15 | \
: demon whip w:15 | demon trident w:15 | wand of draining | scroll of torment | \
: staff of death | rod of demonology w:5 | \
: bottled efreet w:5 | lantern of shadows w:5 | book of necromancy | book of death | \
: book of unlife | randbook disc:necromancy w:5 | necronomicon w:1 | \
: grand grimoire w:1 | scythe unrand:scythe_of_curses w:1 | \
: long sword unrand:sword_of_zonguldrok w:1 | mace unrand:sceptre_of_torment w:1")
KFEAT: a = altar_kikubaaqudgha / altar_yredelemnul / altar_makhleb / \
altar_beogh w:1 / altar_lugonu w:1
MAP
... ...
.G.a.s.G.
... ...
ENDMAP
# Items related to the good gods thematically; healing, silver, holy wrath, etc.
NAME: nicolae_good_shop
DEPTH: D:6-
TAGS: no_monster_gen no_trap_gen
SHUFFLE: _s
KFEAT: s = general shop type:Hallowed suffix:Reliquary ; \
potion of heal wounds | potion of curing | potion of restore abilities | \
wand of heal wounds | dart ego:silver w:2 | javelin ego:silver w:2 | \
bolt ego:silver w:2 | any weapon ego:holy_wrath | scroll of holy word | \
sling bullet ego:silver w:2 | amulet of faith w:2 | potion of cure mutation | \
ring of life protection w:5 | any armour ego:positive_energy w:5
KFEAT: _ = altar_the_shining_one / altar_zin / altar_elyvilon
MONS: angel
MAP
nnn
n1n
nnn
._.
...
.s.
ENDMAP
# All bardings, all the time.
NAME: nicolae_barding_shop
DEPTH: D:8-, Snake, !Snake:$
TAGS: transparent
: if you.branch() == "Snake" then
KMONS: s = naga w:50 / naga warrior
: else
KMONS: s = centaur w:50 / centaur warrior
: end
MAP
KFEAT: s = armour shop type:Specialty suffix:Armours count:6 use_all ; \
naga barding | naga barding | naga barding good_item | \
centaur barding | centaur barding | centaur barding good_item
.......
..xxx..
.x...x.
.x.s.x.
.x...x.
..xxx..
.......
ENDMAP
# Sells conjurations-heavy books, destructive wands and rods, etc.
NAME: nicolae_blasting_shop
DEPTH: D:8-
TAGS: no_trap_gen no_monster_gen no_item_gen
MARKER: s = lua:fog_machine { cloud_type = "flame", \
pow_min = 3, pow_max = 5, delay_min = 50, delay_max = 90, \
start_clouds = 1, size = 3, walk_dist = 0, spread_rate= 0 }
KFEAT: s = general shop type:Demolitions suffix:Depot ; \
book of conjurations | book of power | book of annihilations | \
randbook disc:conjuration | book of the tempests | book of clouds | \
wand of fire | wand of fireball | wand of flame | wand of disintegration | \
wand of frost | wand of cold | wand of lightning | wand of magic darts | \
staff of conjuration | lightning rod | rod of inaccuracy | \
rod of destruction | rod of striking | dart ego:exploding | \
arrow ego:exploding | bolt ego:exploding | tome of destruction | \
sling bullet ego:exploding | scroll of immolation | book of flames | \
book of fire | book of air | manual of conjurations
FTILE: ' = floor_rough_red
COLOUR: ' = red
MAP
...
..x..
..'''..
.x's'x.
..'''..
..x..
...
ENDMAP
|
