Attached Files |
overflows 0213.des [^] (14,601 bytes) 2021-02-13 21:45 [Show Content] [Hide Content]# Ashenzari overflow altars ####################################################
NAME: nicolae_ashenzari_skybound
TAGS: temple_overflow_ashenzari temple_overflow_1 decor
DEPTH: D:2-
KFEAT: _ = altar_ashenzari
COLOUR: m = blue
: interest_check(_G)
MAP
..@..
.......
...mmmmm...
..mmm...mmm..
.mm.v._.v.mm.
.m..v...v..m.
mm..vv+vv..mm
m...........m
m .@. m
ENDMAP
# Elyvilon overflow altars #####################################################
NAME: nicolae_elyvilon_peaceful_grove
TAGS: temple_overflow_elyvilon temple_overflow_1 transparent no_monster_gen \
no_item_gen no_trap_gen
DEPTH: D:2-
KFEAT: _ = altar_elyvilon
KMONS: P = bush w:20 / nothing
KMONS: _ = patrolling butterfly att:good_neutral
: interest_check(_G)
MAP
ww.PtttP.ww
wwP..P..Pww
.PPtt.ttPP.
P.ttP.Ptt.P
t.tP...Pt.t
tP..._...Pt
t.tP...Pt.t
P.ttP.Ptt.P
.PPtt.ttPP.
wwP..P..Pww
ww.PtttP.ww
ENDMAP
NAME: nicolae_elyvilon_temple_path
TAGS: temple_overflow_elyvilon temple_overflow_1 decor no_monster_gen \
no_pool_fixup no_item_gen no_trap_gen
DEPTH: D:2-
SUBST: p = ppp....
KMONS: p = plant
KFEAT: _ = altar_elyvilon
: interest_check(_G)
MAP
ccccc
ccwwwcc @ppppppppp
ccwwUwwccppcppcppcp
cww...wwwwwwwwwwwww
cwU._..............@
cww...wwwwwwwwwwwww
ccwwUwwccppcppcppcp
ccwwwcc @ppppppppp
ccccc
ENDMAP
# Gozag overflow altars ########################################################
NAME: nicolae_gozag_conspicuous_consumption
TAGS: temple_overflow_gozag temple_overflow_1 no_pool_fixup decor transparent \
no_monster_gen no_item_gen no_trap_gen
DEPTH: D:2-
KFEAT: _ = altar_gozag
TILE: G = dngn_golden_statue
TILE: n = dngn_transparent_stone_yellow
FTILE: ._Gn$U = floor_limestone
COLOUR: .$GnU = yellow
KPROP: $ = no_tele_into
KMASK: $n = opaque
# This turns out to be a couple hundo per item stack.
KITEM: $ = gold level:5000
: set_feature_name("granite_statue", "golden statue")
: interest_check(_G)
MAP
.....
G...._....G
...G...G...
..UwwwwwU..
..GwnnnnnwG..
...wn$$$nw...
._.wn$$$nw._.
...wn$$$nw...
..GwnnnnnwG..
..UwwwwwU..
...G...G...
G...._....G
.....
ENDMAP
# Hepliaklqana overflow altars #################################################
NAME: nicolae_hepliaklqana_ecumenical_no_more
# A long-forgotten ecumenical temple. Only Hepliaklqana clearly remains,
# although a few forgotten altars are still around.
TAGS: temple_overflow_hepliaklqana temple_overflow_1 transparent decor \
no_monster_gen no_item_gen no_trap_gen
WEIGHT: 5
DEPTH: D:2-
NSUBST: A = - / A
NSUBST: H = _ / - / A
NSUBST: A = A / . / AAA-..
NSUBST: P = 4:W / Wmm / m
SUBST: ' = '''.
SUBST: c = ccx
KMONS: Wm = plant / nothing
FTILE: WVm = floor_mud
COLOUR: m = darkgrey
FTILE: ' = floor_w_marble
COLOUR: ' = white
FTILE: _-A = floor_limestone
COLOUR: A = yellow
KFEAT: WS = W
KFEAT: Am' = .
KFEAT: _ = altar_hepliaklqana
KFEAT: - = altar_ecumenical
: interest_check(_G)
MAP
xxxxx.@.xxxxx
xxccxx+xxccxx
xccc''.''cccx
xcc''A'A''ccx
xc'''''''''cx
xc'A'PPP'A'cx
xc'''PVP'''cx
xc'H'PPP'H'cx
xc'''''''''cx
xcc''H'H''ccx
xccc'''''cccx
xxcccccccccxx
xxxxxxxxxxxxx
ENDMAP
NAME: nicolae_hepliaklqana_hazy_memory
TAGS: temple_overflow_hepliaklqana temple_overflow_1 transparent decor
DEPTH: D:2-
MONS: plant
SUBST: ' = ..', . = ...1
CLEAR: '
KFEAT: _ = altar_hepliaklqana
MARKER: _ = lua:fog_machine { cloud_type = "thin mist", size = 1, pow_min = 5, \
pow_max = 7, delay = 10, start_clouds = 1, walk_dist = 5, spread_rate = 10 }
: interest_check(_G)
MAP
'''
''''.''''
'.'.'.'.'
''.'''.''
''.'...'.''
'.''._.''.'
''.'...'.''
''.'''.''
'.'.'.'.'
''''.''''
'''
ENDMAP
NAME: nicolae_hepliaklqana_hippocampus
# Or should that be "heppocampus"...?
TAGS: temple_overflow_hepliaklqana temple_overflow_1 transparent decor
DEPTH: D:2-
KFEAT: _ = altar_hepliaklqana
SUBST: D = cxx, C = cx
: interest_check(_G)
MAP
xxxxxxxx
@....xxxx
xxx..xxx
xxxxxxxx.xxx
xcccccxx..xx
xc...cxx..xx
xc._.cxD..xx
xc...cxD..Dx
xc..ccxD..Dx
xc...CC...Dx
xc........Dx
xcC......DDx
xxCCCCCDDDxx
xxxxxxxxxxxx
ENDMAP
NAME: nicolae_hepliaklqana_monster_ancestors
TAGS: temple_overflow_hepliaklqana temple_overflow_1 transparent \
patrolling no_item_gen no_monster_gen no_trap_gen
DEPTH: D:2-9
SHUFFLE: Aa/Bb/Cc/Dd
KFEAT: _ = altar_hepliaklqana
KMONS: A = goblin
KMONS: a = spectral goblin
KMONS: B = kobold
KMONS: b = spectral kobold
KMONS: C = hobgoblin
KMONS: c = spectral hobgoblin
KMONS: D = orc
KMONS: d = spectral orc
: interest_check(_G)
MAP
xxxxxxxxx
xxwwwwwxx
x..A....x
+....._.x
x..a....x
xxwwwwwxx
xxxxxxxxx
ENDMAP
# Kikubaaqudgha overflow altars ################################################
NAME: nicolae_kikubaaqudgha_miasma_corner
TAGS: temple_overflow_kikubaaqudgha temple_overflow_1 no_item_gen no_trap_gen \
no_monster_gen transparent decor
DEPTH: D:3-
COLOUR: c = darkgrey
MARKER: M = lua:fog_machine { cloud_type = "foul pestilence", pow_min = 10, \
pow_max = 20, delay_min = 1, delay_max = 1, size = 1, walk_dist = 0, \
spread_rate = 0 }
KFEAT: _ = altar_kikubaaqudgha
: interest_check(_G)
MAP
.
ccc.ccc
cM...Mc
c.....c
...._....
c.....c
cM...Mc
ccc.ccc
.
ENDMAP
# Qazlal overflow altars ######################################################
NAME: nicolae_qazlal_scattered_showers
# The rain is localized to a 5x5 square centered on the altar.
# There's some rain water that occasionally gets deep but it's passable.
TAGS: temple_overflow_qazlal temple_overflow_1 transparent decor \
no_trap_gen no_item_gen no_monster_gen
DEPTH: D:2-
KFEAT: _ = altar_qazlal
MARKER: _ = lua:fog_machine { cloud_type = "rain", pow_min = 10, \
pow_max = 15, delay_min = 5, delay_max = 15, size = 1, walk_dist = 2, \
spread_rate = 0 }
: interest_check(_G)
MAP
.......
.......
.......
..._...
.......
.......
.......
ENDMAP
# Sif Muna overflow altars #####################################################
NAME: nicolae_sif_muna_condensation
TAGS: temple_overflow_sif_muna temple_overflow_1 transparent decor \
no_trap_gen no_item_gen no_monster_gen no_pool_fixup
DEPTH: D:2-
FTILE: ._w = floor_marble
COLOUR: . = blue
KFEAT: _ = altar_sif_muna
MARKER: _ = lua:fog_machine { cloud_type = "magical condensation", \
pow_min = 5, pow_max = 15, delay_min = 5, delay_max = 20, size = 1, \
walk_dist = 3, spread_rate = 1 }
: interest_check(_G)
MAP
.......
.wwwww.
.wwwww.
..._ww.
.wwwww.
.wwwww.
.......
ENDMAP
NAME: nicolae_sif_muna_little_library
TAGS: temple_overflow_sif_muna temple_overflow_1 decor no_item_gen \
no_monster_gen no_trap_gen
DEPTH: D:2-
NSUBST: X = + / x
KPROP: b = no_tele_into
KITEM: b = any randbook ident:all owner:Sif_Muna unobtainable
KFEAT: _ = altar_sif_muna
FTILE: b._nc+ = floor_marble
COLOUR: b.nc+ = blue
: interest_check(_G)
MAP
xxxxXXXx
xccc...X
xcbn...X
xcbn._.X
xcbn...X
xccc...X
xxxxXXXx
ENDMAP
# Uskayaw overflow altars ######################################################
NAME: nicolae_uskayaw_dance_hall
# Either a square dance or a round dance depending on how the shuffle goes.
TAGS: temple_overflow_uskayaw temple_overflow_1 transparent decor
DEPTH: D:2-
SHUFFLE: Gg
SUBST: g : ., b : bvcmn
KFEAT: _ = altar_uskayaw
: interest_check(_G)
MAP
xxxx.........
x......GgG...
x.b...g...g..
x....G.....G.
._..g.....g.
x....G.....G.
x.b...g...g..
x......GgG...
xxxx.........
ENDMAP
NAME: nicolae_uskayaw_dance_studio
TAGS: temple_overflow_uskayaw temple_overflow_1 no_item_gen no_monster_gen \
transparent patrolling
DEPTH: D:2-
MONS: goblin, kobold
NSUBST: D = 2:1 / 2:2
KMONS: _ = big kobold
KFEAT: _ = altar_uskayaw
: interest_check(_G)
MAP
xxxx+xxxx
xmmm.mmmx
xm.....mx
xm.DDD.mx
xm.D_D.mx
xm.DDD.mx
xm.....mx
xmmmmmmmx
xxxxxxxxx
ENDMAP
NAME: nicolae_uskayaw_en_pointe
TAGS: temple_overflow_uskayaw temple_overflow_1 no_item_gen no_monster_gen \
no_trap_gen patrolling generate_awake transparent decor
DEPTH: D:2-
MONS: dancing weapon ; mundane short sword, dancing weapon ; mundane falchion, \
dancing weapon ; mundane spear , dancing weapon ; mundane dagger
KPROP: 'D = no_tele_into
NSUBST: D = 2:1 / 2:2 / 2:3 / 2:4
TILE: n = dngn_transparent_stone_red
TILE: c = dngn_stone_wall_lightred
COLOUR: n = red
COLOUR: c = lightred
KMASK: '1234n = opaque
KFEAT: _ = altar_uskayaw
: interest_check(_G)
MAP
.............
...nnnnncccc...
..nnD'Dnn..ccc.
..nDn'nDnn...c.
@.n''n'''n._.+.
..nDn'nDnn...c.
..nnD'Dnn..ccc.
...nnnnncccc...
.............
ENDMAP
NAME: nicolae_uskayaw_murder_on_the_dancefloor
# But you'd better not kill the groove.
TAGS: temple_overflow_uskayaw temple_overflow_1 no_item_gen no_monster_gen \
transparent
DEPTH: D:2-
KFEAT: _ = altar_uskayaw
NSUBST: . = 4:k / 3=k.
SUBST: . = ..b, k = kkK
: dgn.delayed_decay(_G, "kK","random corpse")
KPROP: bK = bloody
KFEAT: b = .
COLOUR: ._bkK = disco
FTILE: ._bkK = floor_pebble
: interest_check(_G)
MAP
xxxx@xxxx
x.......x
x.......x
x.......x
@..._...@
x.......x
x.......x
x.......x
xxxx@xxxx
ENDMAP
NAME: nicolae_uskayaw_suspiria
# https://www.youtube.com/watch?v=vpULWBT1WEg
TAGS: temple_overflow_uskayaw temple_overflow_1 transparent decor
DEPTH: D:2-
SHUFFLE: Aa, Bb
SUBST: a : l, A : ...l, b : l, B : .l, C : ...l, D : ...l, E : ...l, \
F : ...l, G : .lll, H : ...l, I : ...l, J : ...l
KPROP: l = no_cloud_gen
KFEAT: _ = altar_uskayaw
: interest_check(_G)
MAP
xxxxxxlll..H..ll
x.bllB.E..ll.CGl
x.....F.ll..I.D.
x_.lll.J...A.a.@
x.....F.ll..I.D.
x.bllB.E..ll.CGl
xxxxxxlll..H..ll
ENDMAP
# Vehumet overflow altars ######################################################
NAME: nicolae_vehumet_altar_sigil
# It's part of the design from the Vehumet altar tile.
TAGS: temple_overflow_vehumet temple_overflow_1 no_item_gen transparent decor
DEPTH: D:2-
FTILE: ._bg+ = floor_pebble
FTILE: _ = floor_pebble_lightgreen
COLOUR: .C = white
COLOUR: bc+ = lightblue
COLOUR: g = lightgreen
KFEAT: _ = altar_vehumet
KFEAT: bg = .
KFEAT: C = c
: interest_check(_G)
MAP
ccc+ccc
cc..g..cc
c..bbb..c
c.b.g.b.c
+gbg_gbg+
c.b.g.b.c
c..bbb..c
cc..g..cc
ccc+ccc
ENDMAP
NAME: nicolae_vehumet_radiance
TAGS: temple_overflow_vehumet temple_overflow_1 no_trap_gen transparent decor
DEPTH: D:2-
SHUFFLE: AaBbCcDd / BbAaDdCc, Aa, Cc
SUBST: AC = X, acBbDd = ., X : cb
KFEAT: _ = altar_vehumet
: interest_check(_G)
MAP
xxxxx
.......
..dDdDd..
..DCcCcCD..
..dc.bBb.cd..
x.DC.BAaAB.CD.x
x.dcba...abcd.x
x.DCBA._.ABCD.x
x.dcba...abcd.x
x.DC.BAaAB.CD.x
..dc.bBb.cd..
..DCcCcCD..
..dDdDd..
.......
xxxxx
ENDMAP
# Wu Jian overflow altars ######################################################
NAME: nicolae_wu_jian_glorious_leap
# As an enticement to join, the Wu Jian Council has placed weapons beyond lava,
# but you can get to them if you know how to wall jump off of the metal walls.
# You can also get to them in other ways, of course, which is why most of the
# weapons are just plain.
TAGS: temple_overflow_wu_jian temple_overflow_1 no_monster_gen no_item_gen \
no_trap_gen
DEPTH: D:4-, !D:$
WEIGHT: 5
NSUBST: i = I / i
KITEM: I = any weapon level:-2
KITEM: i = any weapon
KFEAT: _ = altar_wu_jian
KPROP: l = no_cloud_gen
: interest_check(_G)
MAP
xxxxxxxxxxxxxxx
xccccccccvccccx
xcccilll.....cx
xcccivlll....cx
xc>+i..ll._...+
xcccivlll....cx
xcccilll.....cx
xccccccccvccccx
xxxxxxxxxxxxxxx
ENDMAP
NAME: nicolae_wu_jian_immortal_techniques
# Abstract representations of the moves of Wu Jian's three martial arts.
# The green space is where you start, the red space is where you move to,
# the statue is where the monster is.
TAGS: temple_overflow_wu_jian temple_overflow_1 transparent \
no_monster_gen no_item_gen decor
DEPTH: D:2-
FTILE: Y = floor_pebble_lightgreen
FTILE: R = floor_pebble_lightred
COLOUR: Y = green
COLOUR: R = red
KFEAT: _ = altar_wu_jian
KFEAT: YR = .
: interest_check(_G)
MAP
cc+cccccc
c.Y.c.RRc
c.R...YGc
c.G.c.RRc
ccnccc.cc
c...c...c
c._..RGYc
c...c...c
ccccccccc
ENDMAP
NAME: nicolae_wu_jian_wuxing_cycle
# The five elements, or five phases, Wood, Fire, Earth, Metal, Water,
# in a cycle of either mutual generation or mutual overcoming.
TAGS: temple_overflow_wu_jian temple_overflow_1 transparent \
no_monster_gen no_item_gen no_pool_fixup decor
DEPTH: D:2-
SHUFFLE: tlcvw/lcvwt/cvwtl/vwtlc/wtlcv/tcwlv/cwlvt/wlvtc/lvtcw/vtwcl
NSUBST: Q = 4:@ / x
KPROP: l = no_cloud_gen
KFEAT: _ = altar_wu_jian
: interest_check(_G)
MAP
xxQxx
xx.....xx
Q.........Q
x......ll...x
x..tt..ll...x
x...tt........x
x.............x
Q......_..cc..Q
x..ww.....cc..x
x..ww.........x
x.....vv....x
x.....vv....x
Q.........Q
xx.....xx
xxQxx
ENDMAP
# Yredelemnul overflow atlars ##################################################
NAME: nicolae_yredelemnul_corpse_copse
TAGS: temple_overflow_yredelemnul temple_overflow_1 no_monster_gen no_item_gen \
transparent patrolling
DEPTH: D:2-
# Statistically, the probability that none of the edge glyphs will end up as .
# and the level builder won't be able to connect the vault is extremely small.
# ...but not zero. Thus:
NSUBST: Z = . / T
NSUBST: t = . / ttT
SUBST: T = tt.
: nsubst( ". = " .. you.absdepth() .. ":M / 1:M. / ." )
KMONS: M = zombie
KFEAT: _ = altar_yredelemnul
COLOUR: t = lightgrey w:5 / darkgrey w:5 / brown
TILE: t = dngn_tree_dead
: set_feature_name("tree", "dead tree")
: interest_check(_G)
MAP
ZZZZZ
ZT.T.TZ
ZT.T.T.TZ
ZT.ttttt.TZ
Z.Tt...tT.Z
ZT.t._.t.TZ
Z.Tt...tT.Z
ZT.ttttt.TZ
ZT.T.T.TZ
ZT.T.TZ
ZZZZZ
ENDMAP
NAME: nicolae_yredelemnul_ghost_church
TAGS: temple_overflow_yredelemnul temple_overflow_1 transparent \
luniq_player_ghost no_trap_gen no_monster_gen no_item_gen
DEPTH: D:3-
WEIGHT: 5
KPROP: dO' = no_tele_into
NSUBST: d = * / $ / %
KFEAT: ' = .
KFEAT: _ = altar_yredelemnul
KMONS: O = player ghost
KMONS: z = zombie
: interest_check(_G)
MAP
xxxxxxxxxxx
xxxcccccxxx
xxcc...ccxx
xxcz._.zcxx
xccc...cccx
xc.......cx
xc.n===n.cx
xc.n'O'n.cx
+..ndddn..+
xcccccccccx
xxxxxxxxxxx
ENDMAP
################################################################################
gozag 2.des [^] (740 bytes) 2021-02-25 20:11 [Show Content] [Hide Content]NAME: nicolae_gozag_conspicuous_consumption
TAGS: temple_overflow_gozag temple_overflow_1 no_pool_fixup decor \
transparent no_monster_gen no_item_gen no_trap_gen
DEPTH: D:2-
WEIGHT: 1
KFEAT: _ = altar_gozag
TILE: G = dngn_golden_statue
TILE: n = dngn_transparent_stone_yellow
TILE: m = dngn_transparent_wall_yellow
FTILE: ._Gmn$U = floor_limestone
COLOUR: .Gmn$U = yellow
KPROP: $ = no_tele_into
KMASK: $ = opaque
KITEM: $ = gold
: set_feature_name("granite_statue", "golden statue")
: interest_check(_G)
MAP
.....
G...._....G
...G...G...
..UwwwwwU..
..GwnmmmnwG..
...wm$$$mw...
._.wm$$$mw._.
...wm$$$mw...
..GwnmmmnwG..
..UwwwwwU..
...G...G...
G...._....G
.....
ENDMAP
sif muna 2.des [^] (464 bytes) 2021-03-03 01:00 [Show Content] [Hide Content]NAME: nicolae_sif_muna_little_library
TAGS: temple_overflow_sif_muna temple_overflow_1 no_trap_gen
DEPTH: D:2-
NSUBST: D = + / x
KPROP: a = no_tele_into
KMASK: a = no_item_gen
KMASK: a = no_monster_gen
KITEM: a = any randbook ident:all owner:Sif_Muna slevels:1
KFEAT: _ = altar_sif_muna
FTILE: a._mc+ = floor_marble
COLOUR: a.mc+ = blue
: interest_check(_G)
MAP
xxxxDDDx
xccc...D
xcam...D
xcam._.D
xcam...D
xccc...D
xxxxDDDx
ENDMAP
|